Memo/Terraform/for_each

for_each: ループ †

v0.12.6以降のループ処理について。

countの問題点:

• countが変わると、count.indexに紐付いたidも変わるため、リソースが再生成される。countが増える分には対応できるが、countが減る場合に問題が出る。
• 例: count=2の状態で構築し、その後2台を追加(count=4)後、古い2台を削除(count=2)したい場合。count.index=0,1だけを削除/変更したい場合に対応できない。countを4から2に減らすと、count.index=2,3が削除/変更される。

Manage Similar Resources with For Each | Terraform - HashiCorp Learn:

• 変数を元に、リソース自体をループできる。keyを静的なuniq idで指定すれば、要素数が変わっても問題が無い。
• map型は each.key, each.valueで参照可能
• list型は toset()を指定する。each.key, each.valueで同じ値が参照可能。項目数が増減すると、リソースの生成/破棄が発生する。
  • plan&applyでkeyが動的な値だとエラーが出るようになった。
  • Terraform の for_each では静的な値を利用する｜デロイト トーマツ ウェブサービス株式会社（DWS）公式ブログ

• 記事
  • Terraformで配列をloopする時はfor_eachを使った方がいい - cloudfishのブログ
  • Terraform0.12 のfor_eachで幸せになれるってよ - Qiita

• 環境
  • Terraform v0.12.24

• for_eachの例1: リソース自体が2回実行される

  locals {
    users = [
      "user01",
      "user02",
    ]
  }
  
  resource null_resource user {
    for_each   = toset(local.users)
    triggers  = {
      user = each.value
    }
  }

  • 実行結果

    terraform plan -target null_resource.user
    ...
      # null_resource.user["user01"] will be created
      + resource "null_resource" "user" {
          + id       = (known after apply)
          + triggers = {
              + "user" = "user01"
            }
        }
    
      # null_resource.user["user02"] will be created
      + resource "null_resource" "user" {
          + id       = (known after apply)
          + triggers = {
              + "user" = "user02"
            }
        }

• for_eachでindex値が欲しい場合

  index(local.users, each.value)

countの変わりにfor_eachを使う例 †

• インスタンス毎に変更したい値を変数として定義。(将来的に追加、変更する値も)

  locals {
    site_prefix   = "example1"
    default_ami   = "ami-xxxx"
    web_instances = {
      "web-01" = {
  #      ami           = "ami-xxxx" # 省略すると default_ami が使われるように
        instance_type = "t4g.large"
        subnet_id     = data.aws_subnets.private.ids[0]
        ebs1_size     = 20
      }
      "web-02" = {
        ami           = "ami-xxxx"
        instance_type = "t4g.large"
        subnet_id     = data.aws_subnets.private.ids[1]
        ebs1_size     = 20
      }
    }
  }

• ec2.web.tf

  resource "aws_instance" "web" {
    for_each                    = local.web_instances
    ami                         = ami_name_el9(local.default_ami, each.value.ami)
    instance_type               = each.value.instance_type
    key_name                    = var.key_name
    subnet_id                   = each.value.subnet_id
    iam_instance_profile        = aws_iam_instance_profile.web.id
    disable_api_termination     = var.disable_api_termination
    associate_public_ip_address = false
  
    vpc_security_group_ids = [
      aws_security_group.web.id,
    ]
  
    metadata_options {
      http_tokens = "required"
    }
  
    tags = {
      Name     = "${local.site_prefix}-${each.key}"
    }
  
    root_block_device {
      volume_size = 20
      volume_type = "gp3"
      iops        = 3000
      throughput  = 125
      tags = {
        "Name" = "${local.site_prefix}-${each.key}-root"
      }
    }
  
    ephemeral_block_device {
      device_name  = "/dev/sdb"
      virtual_name = "ephemeral0"
    }
  
    ephemeral_block_device {
      device_name  = "/dev/sdc"
      virtual_name = "ephemeral1"
    }
  
    ephemeral_block_device {
      device_name  = "/dev/sdd"
      virtual_name = "ephemeral2"
    }
  
    ephemeral_block_device {
      device_name  = "/dev/sde"
      virtual_name = "ephemeral3"
    }
  
    credit_specification {
      cpu_credits = "unlimited"
    }
  }
  
  resource "aws_ebs_volume" "web_ebs1" {
    for_each          = local.web_instances
    availability_zone = aws_instance.web[each.key].availability_zone
    size              = each.value.ebs1_size
    type              = "gp3"
    iops              = 3000
    throughput        = 125
    encrypted         = true
  
    tags = {
      Name = "${local.site_prefix}-${each.key}-ebs1"
    }
  }
  
  resource "aws_volume_attachment" "web_ebs1" {
    for_each    = aws_instance.web
    device_name = "/dev/sdf"
    instance_id = each.value.id
    volume_id   = aws_ebs_volume.web_ebs1[each.key].id
  }

map型のリソースの参照 †

• 「aws_ses_email_identity.[*].arn」 を参照したいがエラー。「This object does not have an attribute named "arn".」

  locals {
    ses_email_ids = {
      slack-channel1 = {
        email = "user1@example.com"
      },
    }
  }
  
  resource "aws_ses_email_identity" "main" {
    for_each = local.ses_email_ids
    email    = each.value.email
  }

• 修正

    ses_id_arns      = concat(
      values(aws_ses_email_identity.main)[*].arn,
      [data.aws_ses_domain_identity.domain1.arn],
    )

key, value以上の複数のパラメータを指定したい場合 †

• valueの参照は以下のいずれかで可能
  • each.value.home
  • lookup(each.value, "home")

• example.tf

  variable users {
    type = map(map(string))
    default = {
      user01 = {
        home = "/home/user01"
        shell = "/bin/bash"
      }
      www01 = {
        home = "/var/www/html"
        shell = "/bin/false"
      }
    }
  }
  
  resource null_resource user {
    for_each   = var.users
    triggers  = {
      user = each.key
      home = each.value.home
      shell = each.value.shell
    }
  }

  • 実行結果

    terraform plan
    ...
      # null_resource.user["user01"] will be created
      + resource "null_resource" "user" {
          + id       = (known after apply)
          + triggers = {
              + "home"  = "/home/user01"
              + "shell" = "/bin/bash"
              + "user"  = "user01"
            }
        }
    
      # null_resource.user["www01"] will be created
      + resource "null_resource" "user" {
          + id       = (known after apply)
          + triggers = {
              + "home"  = "/var/www/html"
              + "shell" = "/bin/false"
              + "user"  = "www01"
            }
        }
    
    Plan: 2 to add, 0 to change, 0 to destroy.

for_eachリソースをoutputしたい場合 †

• resource["string"].attr が必要。

output "user_home" {
  value = [ for value in null_resource.user : value.home ]
}

list(map) 型をfor_eachでループ †

• 「for_each = local.ses_dkim」はエラーになる

  locals {
    # ses dkimのdataリソースで参照したほうが良いが、まだ存在しない
    ses_dkim = [
      {
        "type"  = "CNAME"
        "name"  = "dummy1._domainkey.example.com"
        "value" = "dummy1.dkim.amazonses.com"
      },
      {
        "type"  = "CNAME"
        "name"  = "dummy2._domainkey.example.com"
        "value" = "dummy2.dkim.amazonses.com"
      },
      {
        "type"  = "CNAME"
        "name"  = "dummy3._domainkey.example.com"
        "value" = "dummy3.dkim.amazonses.com"
      },
    ]
  }
  
  resource "aws_route53_record" "ses_dkim" {
    for_each = { for i in local.ses_dkim : i.name => i }
    zone_id = data.aws_route53_zone.example_com.zone_id
    name    = each.value.name
    type    = each.value.type
    ttl     = "600"
    records = [each.value.value]
  }

Software

• 自作ソフト
• wiki自作プラグイン
• 利用規定
• ランキング
• 雑誌等掲載履歴

Programming

Game

雑記

連絡先

• MenuBar
• RightBar
• :admin
  

人気の10件

最新の10件